mirror of
https://github.com/github/codeql.git
synced 2026-06-01 11:56:17 +02:00
ba0f24f9f4
The shared CFG creates multiple ControlFlowNodes per AST node in conditional contexts (e.g. afterTrue/afterFalse for boolean conditions, empty/non-empty for for-loops, matched/unmatched for match cases). These splits matter for control-flow analysis, but for dataflow — where we ask 'what is the value of this expression?' — we need exactly one representative per AST or we double-count calls, arguments, and store steps. This adds Cfg::isCanonicalAstNodeRepresentative as a purely structural pick: for split ASTs it selects the 'positive' outcome variant; for non-split ASTs it selects the unique variant. The picker is implemented via genuine-outcome helpers that work around the shared CFG's cross-kind isAfterValue fallback (ControlFlowGraph.qll:870-892), see the doc on isGenuineAfterTrue for details. The TCfgNode-family newtypes in DataFlowPublic, TNormalCall and TPotentialLibraryCall in DataFlowDispatch, and the SSA-projected use-use/def-use steps in DataFlowPrivate are all routed through the canonical filter. DataFlowConsistency and the test UnresolvedCalls helper qualify their CallNode casts with Cfg:: to keep working. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
40 lines
1.4 KiB
Plaintext
40 lines
1.4 KiB
Plaintext
import python
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
private import semmle.python.dataflow.new.internal.PrintNode
|
|
private import semmle.python.dataflow.new.internal.DataFlowPrivate as DataFlowPrivate
|
|
private import semmle.python.ApiGraphs
|
|
import utils.test.InlineExpectationsTest
|
|
|
|
signature module UnresolvedCallExpectationsSig {
|
|
predicate unresolvedCall(Cfg::CallNode call);
|
|
}
|
|
|
|
module DefaultUnresolvedCallExpectations implements UnresolvedCallExpectationsSig {
|
|
predicate unresolvedCall(Cfg::CallNode call) {
|
|
Cfg::isCanonicalAstNodeRepresentative(call) and
|
|
not exists(DataFlowPrivate::DataFlowCall dfc |
|
|
exists(dfc.getCallable()) and dfc.getNode() = call
|
|
) and
|
|
not DataFlowPrivate::resolveClassCall(call, _) and
|
|
not call = API::builtin(_).getACall().asCfgNode()
|
|
}
|
|
}
|
|
|
|
module MakeUnresolvedCallExpectations<UnresolvedCallExpectationsSig Impl> {
|
|
private module UnresolvedCallExpectations implements TestSig {
|
|
string getARelevantTag() { result = "unresolved_call" }
|
|
|
|
predicate hasActualResult(Location location, string element, string tag, string value) {
|
|
exists(location.getFile().getRelativePath()) and
|
|
exists(Cfg::CallNode call | Impl::unresolvedCall(call) |
|
|
location = call.getLocation() and
|
|
tag = "unresolved_call" and
|
|
value = prettyExpr(call.getNode()) and
|
|
element = call.toString()
|
|
)
|
|
}
|
|
}
|
|
|
|
import MakeTest<UnresolvedCallExpectations>
|
|
}
|