mirror of
https://github.com/github/codeql.git
synced 2026-06-30 09:05:28 +02:00
ce66a466dd
Flips the Python dataflow trunk from the legacy CFG (semmle/python/Flow.qll) and legacy ESSA SSA (semmle/python/essa/*) to the new shared CFG facade (semmle.python.controlflow.internal.Cfg) and the new SSA adapter (semmle.python.dataflow.new.internal.SsaImpl), both introduced additively in the preceding PRs in this stack. This is the trunk-flip equivalent of the original draft PR #21894 (kept around as documentation), rebased on top of the four preparatory PRs: P1: Remove AstNode.getAFlowNode() and rewrite callers (#21919). P2: Qualify Flow.qll's AST references with Py:: prefix (#21920). P3: Add new shared-CFG-backed control flow graph (#21921). P4: Add new shared-SSA-backed SSA adapter (#21923). The Python dataflow library (semmle/python/dataflow/new/) now imports the new CFG facade and SSA adapter. All CFG-typed predicates (ControlFlowNode, CallNode, BasicBlock, NameNode, AttrNode, ...) are qualified with the Cfg:: prefix; SSA references switch from EssaVariable/EssaDefinition to SsaImpl::Definition/SourceVariable. GuardNode is redesigned to use the new CFG's outcome-node model (isAfterTrue / isAfterFalse) instead of the legacy ConditionBlock + flipped indirection. Only BarrierGuard<...> is preserved as public API. Framework files (Bottle, FastApi, Django, Tornado, Pyramid, Stdlib, ...) are updated to take CFG nodes from the new facade. A handful of dataflow consistency tweaks for the new CFG: - Augmented-assignment targets are treated as both load and store. - 'from X import *' produces uncertain SSA writes for unknown names. - CFG nodes are canonicalised so dataflow does not see equivalent pre/post-order pairs as distinct nodes. Two AST tweaks for the new CFG: - AstNodeImpl: omit PEP 695 type-parameter names from FunctionDefExpr / ClassDefExpr children. - ImportResolution: drop the legacy essa import. Test churn (~175 files): reblessed library- and query-test .expected files reflect slightly different CFG granularity, different toString output, and a handful of true alert deltas in security queries. Verification: all 367 lib + src + consistency-queries compile clean. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
56 lines
2.1 KiB
Plaintext
56 lines
2.1 KiB
Plaintext
/**
|
|
* @name Modification of dictionary returned by locals()
|
|
* @description Modifications of the dictionary returned by locals() are not propagated to the local variables of a function.
|
|
* @kind problem
|
|
* @tags quality
|
|
* reliability
|
|
* correctness
|
|
* @problem.severity warning
|
|
* @sub-severity low
|
|
* @precision very-high
|
|
* @id py/modification-of-locals
|
|
*/
|
|
|
|
import python
|
|
private import semmle.python.ApiGraphs
|
|
private import semmle.python.dataflow.new.DataFlow
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
|
|
predicate originIsLocals(Cfg::ControlFlowNode n) {
|
|
// Only consider the `locals()` dictionary within the scope that called `locals()`.
|
|
// Once the dictionary is passed to another scope (e.g. as an argument or via an
|
|
// instance attribute) it is just an ordinary mapping, and modifying it is both
|
|
// meaningful and effective. Restricting to local (intraprocedural) flow ensures we
|
|
// only report modifications in the scope where the `locals()` gotcha actually applies.
|
|
exists(DataFlow::LocalSourceNode src, DataFlow::Node use |
|
|
src = API::builtin("locals").getReturn().asSource() and
|
|
src.flowsTo(use) and
|
|
use.asCfgNode() = n
|
|
)
|
|
}
|
|
|
|
predicate modification_of_locals(Cfg::ControlFlowNode f) {
|
|
originIsLocals(f.(Cfg::SubscriptNode).getObject()) and
|
|
(f.isStore() or f.isDelete())
|
|
or
|
|
exists(string mname, Cfg::AttrNode attr |
|
|
attr = f.(Cfg::CallNode).getFunction() and
|
|
originIsLocals(attr.getObject(mname))
|
|
|
|
|
mname in ["pop", "popitem", "update", "clear"]
|
|
)
|
|
}
|
|
|
|
from AstNode a, Cfg::ControlFlowNode f
|
|
where
|
|
modification_of_locals(f) and
|
|
a = f.getNode() and
|
|
// in module level scope `locals() == globals()`
|
|
// see https://docs.python.org/3/library/functions.html#locals
|
|
// FP report in https://github.com/github/codeql/issues/6674
|
|
not a.getScope() instanceof Module and
|
|
// in class level scope `locals()` reflects the class namespace,
|
|
// so modifications do take effect.
|
|
not a.getScope() instanceof Class
|
|
select a, "Modification of the locals() dictionary will have no effect on the local variables."
|