mirror of
https://github.com/github/codeql.git
synced 2025-12-16 16:53:25 +01:00
78c33ab55a
For now, these have just been made into `private` imports. After doing
this, I went through all of the (now not compiling) files and added in
private imports to the modules that they actually depended on.
I also added an explicit import of `LegacyPointsTo` (even though it may
be unnecessary) in cases where the points-to dependency was somewhat
surprising (and one we want to get rid of). This was primarily inside
the various SSA layers.
For modules inside `semmle.python.{types, objects, pointsto}` I did not
bother, as these are fairly clearly related to points-to.
37 lines
1.2 KiB
Plaintext
37 lines
1.2 KiB
Plaintext
/**
|
|
* @name Membership test with a non-container
|
|
* @description A membership test, such as 'item in sequence', with a non-container on the right hand side will raise a 'TypeError'.
|
|
* @kind problem
|
|
* @tags quality
|
|
* reliability
|
|
* correctness
|
|
* @problem.severity error
|
|
* @sub-severity high
|
|
* @precision high
|
|
* @id py/member-test-non-container
|
|
*/
|
|
|
|
import python
|
|
private import LegacyPointsTo
|
|
|
|
predicate rhs_in_expr(ControlFlowNode rhs, Compare cmp) {
|
|
exists(Cmpop op, int i | cmp.getOp(i) = op and cmp.getComparator(i) = rhs.getNode() |
|
|
op instanceof In or op instanceof NotIn
|
|
)
|
|
}
|
|
|
|
from
|
|
ControlFlowNodeWithPointsTo non_seq, Compare cmp, Value v, ClassValue cls, ControlFlowNode origin
|
|
where
|
|
rhs_in_expr(non_seq, cmp) and
|
|
non_seq.pointsTo(_, v, origin) and
|
|
v.getClass() = cls and
|
|
not Types::failedInference(cls, _) and
|
|
not cls.hasAttribute("__contains__") and
|
|
not cls.hasAttribute("__iter__") and
|
|
not cls.hasAttribute("__getitem__") and
|
|
not cls = ClassValue::nonetype() and
|
|
not cls = Value::named("types.MappingProxyType")
|
|
select cmp, "This test may raise an Exception as the $@ may be of non-container class $@.", origin,
|
|
"target", cls, cls.getName()
|