mirror of
https://github.com/github/codeql.git
synced 2026-02-23 18:33:42 +01:00
ac5a74448f
With `ModuleVariableNode`s now appearing for _all_ global variables (not just the ones that actually seem to be used), some of the tests changed a bit. Mostly this was in the form of new flow (because of new nodes that popped into existence). For some inline expectation tests, I opted to instead exclude these results, as there was no suitable location to annotate. For the normal tests, I just accepted the output (after having vetted it carefully, of course).
45 lines
1.5 KiB
Plaintext
45 lines
1.5 KiB
Plaintext
import python
|
|
import semmle.python.dataflow.new.DataFlow
|
|
private import semmle.python.dataflow.new.internal.DataFlowPrivate
|
|
import FlowTest
|
|
|
|
module MaximalFlowTest implements FlowTestSig {
|
|
string flowTag() { result = "flow" }
|
|
|
|
predicate relevantFlow(DataFlow::Node source, DataFlow::Node sink) {
|
|
source != sink and
|
|
MaximalFlows::flow(source, sink) and
|
|
// exclude ModuleVariableNodes (which have location 0:0:0:0)
|
|
not sink instanceof DataFlow::ModuleVariableNode
|
|
}
|
|
}
|
|
|
|
import MakeTest<MakeTestSig<MaximalFlowTest>>
|
|
|
|
/**
|
|
* A configuration to find all "maximal" flows.
|
|
* To be used on small programs.
|
|
*/
|
|
module MaximalFlowsConfig implements DataFlow::ConfigSig {
|
|
predicate isSource(DataFlow::Node node) {
|
|
exists(node.getLocation().getFile().getRelativePath()) and
|
|
not node.asCfgNode() instanceof CallNode and
|
|
not node.asCfgNode().getNode() instanceof Return and
|
|
not node instanceof DataFlow::ParameterNode and
|
|
not node instanceof DataFlow::PostUpdateNode and
|
|
// not node.asExpr() instanceof FunctionExpr and
|
|
// not node.asExpr() instanceof ClassExpr and
|
|
not DataFlow::localFlowStep(_, node)
|
|
}
|
|
|
|
predicate isSink(DataFlow::Node node) {
|
|
exists(node.getLocation().getFile().getRelativePath()) and
|
|
not any(CallNode c).getArg(_) = node.asCfgNode() and
|
|
not node instanceof DataFlow::ArgumentNode and
|
|
not node.asCfgNode().(NameNode).getId().matches("SINK%") and
|
|
not DataFlow::localFlowStep(node, _)
|
|
}
|
|
}
|
|
|
|
module MaximalFlows = DataFlow::Global<MaximalFlowsConfig>;
|