mirror of
https://github.com/github/codeql.git
synced 2026-06-03 04:40:14 +02:00
a13dfaa44f
Preparatory refactor for the shared-CFG dataflow migration. Deprecates the AstNode.getAFlowNode() cached predicate on the public Python QL API and rewrites all ~140 internal callers across lib/, src/, test/, and tools/ from `expr.getAFlowNode() = cfgNode` to `cfgNode.getNode() = expr`, using ControlFlowNode.getNode() which already exists in Flow.qll. The predicate itself is preserved (with a deprecation note pointing at the new pattern) so external users do not experience churn — they can migrate at their own pace and the AST/CFG hierarchies still get the intended untangling once the deprecation eventually elapses. Semantic noop verified by: - All 361 lib/ + src/ queries compile clean. - All 122 ControlFlow + PointsTo library-tests pass. - All 64 dataflow library-tests pass. - All 113 Variables/Exceptions/Expressions/Statements/Functions/Imports/ Security/CWE-798/ModificationOfParameterWithDefault query-tests pass. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
38 lines
1.3 KiB
Plaintext
38 lines
1.3 KiB
Plaintext
/**
|
|
* @name Nested loops with same variable reused after inner loop body
|
|
* @description Redefining a variable in an inner loop and then using
|
|
* the variable in an outer loop causes unexpected behavior.
|
|
* @kind problem
|
|
* @tags quality
|
|
* reliability
|
|
* correctness
|
|
* @problem.severity error
|
|
* @sub-severity low
|
|
* @precision very-high
|
|
* @id py/nested-loops-with-same-variable-reused
|
|
*/
|
|
|
|
import python
|
|
|
|
predicate loop_variable_ssa(For f, Variable v, SsaVariable s) {
|
|
s.getDefinition().getNode() = f.getTarget() and v = s.getVariable()
|
|
}
|
|
|
|
predicate variableUsedInNestedLoops(For inner, For outer, Variable v, Name n) {
|
|
/* Ignore cases where there is no use of the variable or the only use is in the inner loop. */
|
|
outer.contains(n) and
|
|
not inner.contains(n) and
|
|
/* Only treat loops in body as inner loops. Loops in the else clause are ignored. */
|
|
outer.getBody().contains(inner) and
|
|
exists(SsaVariable s |
|
|
loop_variable_ssa(inner, v, s.getAnUltimateDefinition()) and
|
|
loop_variable_ssa(outer, v, _) and
|
|
s.getAUse().getNode() = n
|
|
)
|
|
}
|
|
|
|
from For inner, For outer, Variable v, Name n
|
|
where variableUsedInNestedLoops(inner, outer, v, n)
|
|
select inner, "Nested for statement $@ loop variable '" + v.getId() + "' of enclosing $@.", n,
|
|
"uses", outer, "for statement"
|