mirror of
https://github.com/github/codeql.git
synced 2026-06-05 21:47:10 +02:00
5b9803e03c
Flips the Python dataflow trunk from the legacy CFG (semmle/python/Flow.qll) and legacy ESSA SSA (semmle/python/essa/*) to the new shared CFG facade (semmle.python.controlflow.internal.Cfg) and the new SSA adapter (semmle.python.dataflow.new.internal.SsaImpl), both introduced additively in the preceding PRs in this stack. This is the trunk-flip equivalent of the original draft PR #21894 (kept around as documentation), rebased on top of the four preparatory PRs: P1: Remove AstNode.getAFlowNode() and rewrite callers (#21919). P2: Qualify Flow.qll's AST references with Py:: prefix (#21920). P3: Add new shared-CFG-backed control flow graph (#21921). P4: Add new shared-SSA-backed SSA adapter (#21923). The Python dataflow library (semmle/python/dataflow/new/) now imports the new CFG facade and SSA adapter. All CFG-typed predicates (ControlFlowNode, CallNode, BasicBlock, NameNode, AttrNode, ...) are qualified with the Cfg:: prefix; SSA references switch from EssaVariable/EssaDefinition to SsaImpl::Definition/SourceVariable. GuardNode is redesigned to use the new CFG's outcome-node model (isAfterTrue / isAfterFalse) instead of the legacy ConditionBlock + flipped indirection. Only BarrierGuard<...> is preserved as public API. Framework files (Bottle, FastApi, Django, Tornado, Pyramid, Stdlib, ...) are updated to take CFG nodes from the new facade. A handful of dataflow consistency tweaks for the new CFG: - Augmented-assignment targets are treated as both load and store. - 'from X import *' produces uncertain SSA writes for unknown names. - CFG nodes are canonicalised so dataflow does not see equivalent pre/post-order pairs as distinct nodes. Two AST tweaks for the new CFG: - AstNodeImpl: omit PEP 695 type-parameter names from FunctionDefExpr / ClassDefExpr children. - ImportResolution: drop the legacy essa import. Test churn (~175 files): reblessed library- and query-test .expected files reflect slightly different CFG granularity, different toString output, and a handful of true alert deltas in security queries. Verification: all 367 lib + src + consistency-queries compile clean. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
51 lines
1.5 KiB
Plaintext
51 lines
1.5 KiB
Plaintext
/**
|
|
* @name An assert statement has a side-effect
|
|
* @description Side-effects in assert statements result in differences between normal
|
|
* and optimized behavior.
|
|
* @kind problem
|
|
* @tags quality
|
|
* reliability
|
|
* correctness
|
|
* @problem.severity error
|
|
* @sub-severity low
|
|
* @precision high
|
|
* @id py/side-effect-in-assert
|
|
*/
|
|
|
|
import python
|
|
private import semmle.python.ApiGraphs
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
|
|
predicate func_with_side_effects(Expr e) {
|
|
exists(string name | name = e.(Attribute).getName() or name = e.(Name).getId() |
|
|
name in [
|
|
"print", "write", "append", "pop", "remove", "discard", "delete", "close", "open", "exit"
|
|
]
|
|
)
|
|
}
|
|
|
|
predicate call_with_side_effect(Call e) {
|
|
exists(Cfg::ControlFlowNode eCfg | eCfg.getNode() = e |
|
|
eCfg =
|
|
API::moduleImport("subprocess")
|
|
.getMember(["call", "check_call", "check_output"])
|
|
.getACall()
|
|
.asCfgNode()
|
|
)
|
|
}
|
|
|
|
predicate probable_side_effect(Expr e) {
|
|
// Only consider explicit yields, not artificial ones in comprehensions
|
|
e instanceof Yield and not exists(Comp c | c.contains(e))
|
|
or
|
|
e instanceof YieldFrom
|
|
or
|
|
e instanceof Call and func_with_side_effects(e.(Call).getFunc())
|
|
or
|
|
e instanceof Call and call_with_side_effect(e)
|
|
}
|
|
|
|
from Assert a, Expr e
|
|
where probable_side_effect(e) and a.contains(e)
|
|
select a, "This 'assert' statement contains an $@ which may have side effects.", e, "expression"
|