mirror of
https://github.com/github/codeql.git
synced 2026-06-05 13:37:06 +02:00
5b9803e03c
Flips the Python dataflow trunk from the legacy CFG (semmle/python/Flow.qll) and legacy ESSA SSA (semmle/python/essa/*) to the new shared CFG facade (semmle.python.controlflow.internal.Cfg) and the new SSA adapter (semmle.python.dataflow.new.internal.SsaImpl), both introduced additively in the preceding PRs in this stack. This is the trunk-flip equivalent of the original draft PR #21894 (kept around as documentation), rebased on top of the four preparatory PRs: P1: Remove AstNode.getAFlowNode() and rewrite callers (#21919). P2: Qualify Flow.qll's AST references with Py:: prefix (#21920). P3: Add new shared-CFG-backed control flow graph (#21921). P4: Add new shared-SSA-backed SSA adapter (#21923). The Python dataflow library (semmle/python/dataflow/new/) now imports the new CFG facade and SSA adapter. All CFG-typed predicates (ControlFlowNode, CallNode, BasicBlock, NameNode, AttrNode, ...) are qualified with the Cfg:: prefix; SSA references switch from EssaVariable/EssaDefinition to SsaImpl::Definition/SourceVariable. GuardNode is redesigned to use the new CFG's outcome-node model (isAfterTrue / isAfterFalse) instead of the legacy ConditionBlock + flipped indirection. Only BarrierGuard<...> is preserved as public API. Framework files (Bottle, FastApi, Django, Tornado, Pyramid, Stdlib, ...) are updated to take CFG nodes from the new facade. A handful of dataflow consistency tweaks for the new CFG: - Augmented-assignment targets are treated as both load and store. - 'from X import *' produces uncertain SSA writes for unknown names. - CFG nodes are canonicalised so dataflow does not see equivalent pre/post-order pairs as distinct nodes. Two AST tweaks for the new CFG: - AstNodeImpl: omit PEP 695 type-parameter names from FunctionDefExpr / ClassDefExpr children. - ImportResolution: drop the legacy essa import. Test churn (~175 files): reblessed library- and query-test .expected files reflect slightly different CFG granularity, different toString output, and a handful of true alert deltas in security queries. Verification: all 367 lib + src + consistency-queries compile clean. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
41 lines
1.4 KiB
Plaintext
41 lines
1.4 KiB
Plaintext
/** Provides classes representing various sources of information about raised exceptions. */
|
|
|
|
import python
|
|
import semmle.python.dataflow.new.DataFlow
|
|
private import semmle.python.ApiGraphs
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
|
|
/**
|
|
* INTERNAL: Do not use.
|
|
*
|
|
* A data-flow node that carries information about a raised exception.
|
|
* Such information should rarely be exposed directly to the user.
|
|
*/
|
|
abstract class ExceptionInfo extends DataFlow::Node { }
|
|
|
|
/** A call to a function from the `traceback` module revealing information about a raised exception. */
|
|
private class TracebackFunctionCall extends ExceptionInfo, DataFlow::CallCfgNode {
|
|
TracebackFunctionCall() {
|
|
this =
|
|
API::moduleImport("traceback")
|
|
.getMember([
|
|
"extract_tb", "extract_stack", "format_list", "format_exception_only",
|
|
"format_exception", "format_exc", "format_tb", "format_stack"
|
|
])
|
|
.getACall()
|
|
}
|
|
}
|
|
|
|
/** A caught exception. */
|
|
private class CaughtException extends ExceptionInfo {
|
|
CaughtException() {
|
|
this.asExpr() = any(ExceptStmt s).getName() and
|
|
this.asCfgNode().(Cfg::NameNode).defines(_)
|
|
}
|
|
}
|
|
|
|
/** A call to `sys.exc_info`. */
|
|
private class SysExcInfoCall extends ExceptionInfo, DataFlow::CallCfgNode {
|
|
SysExcInfoCall() { this = API::moduleImport("sys").getMember("exc_info").getACall() }
|
|
}
|