mirror of
https://github.com/github/codeql.git
synced 2026-06-02 20:30:15 +02:00
4ed5722e3e
Flips the Python dataflow trunk from the legacy CFG (semmle/python/Flow.qll) and legacy ESSA SSA (semmle/python/essa/*) to the new shared CFG facade (semmle.python.controlflow.internal.Cfg) and the new SSA adapter (semmle.python.dataflow.new.internal.SsaImpl), both introduced additively in the preceding PRs in this stack. This is the trunk-flip equivalent of the original draft PR #21894 (kept around as documentation), rebased on top of the four preparatory PRs: P1: Remove AstNode.getAFlowNode() and rewrite callers (#21919). P2: Qualify Flow.qll's AST references with Py:: prefix (#21920). P3: Add new shared-CFG-backed control flow graph (#21921). P4: Add new shared-SSA-backed SSA adapter (#21923). The Python dataflow library (semmle/python/dataflow/new/) now imports the new CFG facade and SSA adapter. All CFG-typed predicates (ControlFlowNode, CallNode, BasicBlock, NameNode, AttrNode, ...) are qualified with the Cfg:: prefix; SSA references switch from EssaVariable/EssaDefinition to SsaImpl::Definition/SourceVariable. GuardNode is redesigned to use the new CFG's outcome-node model (isAfterTrue / isAfterFalse) instead of the legacy ConditionBlock + flipped indirection. Only BarrierGuard<...> is preserved as public API. Framework files (Bottle, FastApi, Django, Tornado, Pyramid, Stdlib, ...) are updated to take CFG nodes from the new facade. A handful of dataflow consistency tweaks for the new CFG: - Augmented-assignment targets are treated as both load and store. - 'from X import *' produces uncertain SSA writes for unknown names. - CFG nodes are canonicalised so dataflow does not see equivalent pre/post-order pairs as distinct nodes. Two AST tweaks for the new CFG: - AstNodeImpl: omit PEP 695 type-parameter names from FunctionDefExpr / ClassDefExpr children. - ImportResolution: drop the legacy essa import. Test churn (~175 files): reblessed library- and query-test .expected files reflect slightly different CFG granularity, different toString output, and a handful of true alert deltas in security queries. Verification: all 367 lib + src + consistency-queries compile clean. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
60 lines
2.0 KiB
Plaintext
60 lines
2.0 KiB
Plaintext
import python
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
import semmle.python.dataflow.new.DataFlow
|
|
import utils.test.InlineExpectationsTest
|
|
private import semmle.python.dataflow.new.internal.PrintNode
|
|
private import semmle.python.dataflow.new.internal.DataFlowPrivate as DataFlowPrivate
|
|
|
|
/**
|
|
* A routing test is designed to test that values are routed to the
|
|
* correct arguments of the correct functions. It is assumed that
|
|
* the functions tested sink their arguments sequentially, that is
|
|
* `SINK1(arg1)`, etc.
|
|
*/
|
|
signature module RoutingTestSig {
|
|
class Argument;
|
|
|
|
string flowTag(Argument arg);
|
|
|
|
predicate relevantFlow(DataFlow::Node fromNode, DataFlow::Node toNode, Argument arg);
|
|
}
|
|
|
|
module MakeTestSig<RoutingTestSig Impl> implements TestSig {
|
|
string getARelevantTag() { result in ["func", Impl::flowTag(_)] }
|
|
|
|
predicate hasActualResult(Location location, string element, string tag, string value) {
|
|
exists(DataFlow::Node fromNode, DataFlow::Node toNode, Impl::Argument arg |
|
|
Impl::relevantFlow(fromNode, toNode, arg)
|
|
|
|
|
location = fromNode.getLocation() and
|
|
element = fromNode.toString() and
|
|
(
|
|
tag = Impl::flowTag(arg) and
|
|
if "\"" + tag + "\"" = fromValue(fromNode) then value = "" else value = fromValue(fromNode)
|
|
or
|
|
// only have result for `func` tag if the function where `arg<n>` is used, is
|
|
// different from the function name of the call where `arg<n>` was specified as
|
|
// an argument
|
|
tag = "func" and
|
|
value = toFunc(toNode) and
|
|
not value = fromFunc(fromNode)
|
|
)
|
|
)
|
|
}
|
|
}
|
|
|
|
pragma[inline]
|
|
private string fromValue(DataFlow::Node fromNode) {
|
|
result = "\"" + prettyNode(fromNode).replaceAll("\"", "'") + "\""
|
|
}
|
|
|
|
pragma[inline]
|
|
private string fromFunc(DataFlow::ArgumentNode fromNode) {
|
|
result = fromNode.getCall().getNode().(Cfg::CallNode).getFunction().getNode().(Name).getId()
|
|
}
|
|
|
|
pragma[inline]
|
|
private string toFunc(DataFlow::Node toNode) {
|
|
result = toNode.getEnclosingCallable().getQualifiedName()
|
|
}
|