mirror of
https://github.com/github/codeql.git
synced 2026-07-03 02:25:29 +02:00
717ff62d70
Preparatory refactor for the shared-CFG dataflow migration. Deprecates the AstNode.getAFlowNode() cached predicate on the public Python QL API and rewrites all ~140 internal callers across lib/, src/, test/, and tools/ from `expr.getAFlowNode() = cfgNode` to `cfgNode.getNode() = expr`, using ControlFlowNode.getNode() which already exists in Flow.qll. The predicate itself is preserved (with a deprecation note pointing at the new pattern) so external users do not experience churn — they can migrate at their own pace and the AST/CFG hierarchies still get the intended untangling once the deprecation eventually elapses. Semantic noop verified by: - All 361 lib/ + src/ queries compile clean. - All 122 ControlFlow + PointsTo library-tests pass. - All 64 dataflow library-tests pass. - All 113 Variables/Exceptions/Expressions/Statements/Functions/Imports/ Security/CWE-798/ModificationOfParameterWithDefault query-tests pass. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
28 lines
798 B
Plaintext
28 lines
798 B
Plaintext
/**
|
|
* @name Non-iterable used in for loop
|
|
* @description Using a non-iterable as the object in a 'for' loop causes a TypeError.
|
|
* @kind problem
|
|
* @tags quality
|
|
* reliability
|
|
* correctness
|
|
* @problem.severity error
|
|
* @sub-severity low
|
|
* @precision high
|
|
* @id py/non-iterable-in-for-loop
|
|
*/
|
|
|
|
import python
|
|
private import LegacyPointsTo
|
|
|
|
from For loop, ControlFlowNodeWithPointsTo iter, Value v, ClassValue t, ControlFlowNode origin
|
|
where
|
|
iter.getNode() = loop.getIter() and
|
|
iter.pointsTo(_, v, origin) and
|
|
v.getClass() = t and
|
|
not t.isIterable() and
|
|
not t.failedInference(_) and
|
|
not v = Value::named("None") and
|
|
not t.isDescriptorType()
|
|
select loop, "This for-loop may attempt to iterate over a $@ of class $@.", origin,
|
|
"non-iterable instance", t, t.getName()
|