mirror of
https://github.com/github/codeql.git
synced 2026-07-30 23:13:01 +02:00
265a31dc1d
Flips the Python dataflow trunk from the legacy CFG (semmle/python/Flow.qll) and legacy ESSA SSA (semmle/python/essa/*) to the new shared CFG facade (semmle.python.controlflow.internal.Cfg) and the new SSA adapter (semmle.python.dataflow.new.internal.SsaImpl), both introduced additively in the preceding PRs in this stack. This is the trunk-flip equivalent of the original draft PR #21894 (kept around as documentation), rebased on top of the four preparatory PRs: P1: Remove AstNode.getAFlowNode() and rewrite callers (#21919). P2: Qualify Flow.qll's AST references with Py:: prefix (#21920). P3: Add new shared-CFG-backed control flow graph (#21921). P4: Add new shared-SSA-backed SSA adapter (#21923). The Python dataflow library (semmle/python/dataflow/new/) now imports the new CFG facade and SSA adapter. All CFG-typed predicates (ControlFlowNode, CallNode, BasicBlock, NameNode, AttrNode, ...) are qualified with the Cfg:: prefix; SSA references switch from EssaVariable/EssaDefinition to SsaImpl::Definition/SourceVariable. GuardNode is redesigned to use the new CFG's outcome-node model (isAfterTrue / isAfterFalse) instead of the legacy ConditionBlock + flipped indirection. Only BarrierGuard<...> is preserved as public API. Framework files (Bottle, FastApi, Django, Tornado, Pyramid, Stdlib, ...) are updated to take CFG nodes from the new facade. A handful of dataflow consistency tweaks for the new CFG: - Augmented-assignment targets are treated as both load and store. - 'from X import *' produces uncertain SSA writes for unknown names. - CFG nodes are canonicalised so dataflow does not see equivalent pre/post-order pairs as distinct nodes. Two AST tweaks for the new CFG: - AstNodeImpl: omit PEP 695 type-parameter names from FunctionDefExpr / ClassDefExpr children. - ImportResolution: drop the legacy essa import. Test churn (~175 files): reblessed library- and query-test .expected files reflect slightly different CFG granularity, different toString output, and a handful of true alert deltas in security queries. Verification: all 367 lib + src + consistency-queries compile clean. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
69 lines
2.3 KiB
Plaintext
69 lines
2.3 KiB
Plaintext
/**
|
|
* @name Predictable token
|
|
* @description Tokens used for sensitive tasks, such as, password recovery,
|
|
* and email confirmation, should not use predictable values.
|
|
* @kind path-problem
|
|
* @precision medium
|
|
* @problem.severity error
|
|
* @security-severity 5
|
|
* @id py/predictable-token
|
|
* @tags security
|
|
* experimental
|
|
* external/cwe/cwe-340
|
|
*/
|
|
|
|
import python
|
|
import semmle.python.dataflow.new.DataFlow
|
|
import semmle.python.ApiGraphs
|
|
import semmle.python.dataflow.new.TaintTracking
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
|
|
class PredictableResultSource extends DataFlow::Node {
|
|
PredictableResultSource() {
|
|
exists(API::Node uuidCallRet |
|
|
uuidCallRet = API::moduleImport("uuid").getMember(["uuid1", "uuid3", "uuid5"]).getReturn()
|
|
|
|
|
this = uuidCallRet.asSource()
|
|
or
|
|
this = uuidCallRet.getMember(["hex", "bytes", "bytes_le"]).asSource()
|
|
)
|
|
}
|
|
}
|
|
|
|
class TokenAssignmentValueSink extends DataFlow::Node {
|
|
TokenAssignmentValueSink() {
|
|
exists(string name | name.toLowerCase().matches(["%token", "%code"]) |
|
|
exists(Cfg::DefinitionNode n | n.getValue() = this.asCfgNode() |
|
|
name = n.(Cfg::NameNode).getId()
|
|
)
|
|
or
|
|
exists(DataFlow::AttrWrite aw | aw.getValue() = this | name = aw.getAttributeName())
|
|
)
|
|
}
|
|
}
|
|
|
|
private module TokenBuiltFromUuidConfig implements DataFlow::ConfigSig {
|
|
predicate isSource(DataFlow::Node source) { source instanceof PredictableResultSource }
|
|
|
|
predicate isSink(DataFlow::Node sink) { sink instanceof TokenAssignmentValueSink }
|
|
|
|
predicate isAdditionalFlowStep(DataFlow::Node nodeFrom, DataFlow::Node nodeTo) {
|
|
exists(DataFlow::CallCfgNode call |
|
|
call = API::builtin("str").getACall() and
|
|
nodeFrom = call.getArg(0) and
|
|
nodeTo = call
|
|
)
|
|
}
|
|
|
|
predicate observeDiffInformedIncrementalMode() { any() }
|
|
}
|
|
|
|
/** Global taint-tracking for detecting "TokenBuiltFromUUID" vulnerabilities. */
|
|
module TokenBuiltFromUuidFlow = TaintTracking::Global<TokenBuiltFromUuidConfig>;
|
|
|
|
import TokenBuiltFromUuidFlow::PathGraph
|
|
|
|
from TokenBuiltFromUuidFlow::PathNode source, TokenBuiltFromUuidFlow::PathNode sink
|
|
where TokenBuiltFromUuidFlow::flowPath(source, sink)
|
|
select sink.getNode(), source, sink, "Token built from $@.", source.getNode(), "predictable value"
|