mirror of
https://github.com/github/codeql.git
synced 2026-05-27 17:41:24 +02:00
26df3945d3
Switches the trunk dataflow library and all in-tree consumers
(frameworks, ApiGraphs, Concepts, regexp, security customisations,
test harness) from the legacy Flow.qll/ESSA stack to the new
shared-CFG facade (Cfg.qll) and the ESSA-shaped adapter on the
shared-SSA library (SsaImpl.qll).
Highlights:
* DataFlowPublic/Private/Dispatch, Attributes, VariableCapture,
IterableUnpacking, ImportResolution, ImportStar, LocalSources,
TaintTrackingPrivate, MatchUnpacking, TypeTrackingImpl,
SsaImpl, Builtins all now qualify CFG/SSA references with
Cfg:: / SsaImpl:: and stop pulling in semmle.python.essa.*.
* AstNodeImpl.qll/Cfg.qll: ImportMember exposes its inner
ImportExpr, DefinitionNode.getValue covers Alias / AnnAssign /
AugAssign / AssignExpr / For-target / Parameter-default,
ForNode is treated as an expression node, AnnotatedExitNode is
canonical, and BoolExprNode.getAnOperand drops the dominance
constraint that did not hold for short-circuit BBs.
* SsaImpl.qll: parameters always get a ParameterDefinition (so
unused parameters still have SSA defs), scope-entry defs for
module globals require an actual store somewhere, scope-exit
has a synthetic use so reaching-defs survives to module
boundary, and the legacy SsaSourceVariable / EssaVariable
surface (getName, getScope, getAUse, getASourceUse,
getAnImplicitUse) is reinstated for downstream queries.
* DataFlowPublic.qll: GuardNode redesigned around the new
structural outcome nodes (isAfterTrue / isAfterFalse). The
legacy ConditionBlock + flipped indirection is gone;
controlsBlock walks UP through 'not' / '==True' / 'is False'
etc. via outcomeOfGuard, accumulating polarity cleanly. Only
BarrierGuard<...> is preserved as public API.
* ModuleVariableNode.getAWrite and LocalFlow::definitionFlowStep
bypass SSA and consult Cfg::NameNode.defines /
Cfg::DefinitionNode.getValue directly, so that write defs
pruned by shared SSA (because the variable has no in-scope
read) still produce dataflow steps.
* Frameworks + downstream consumers: replace
EssaVariable.hasDefiningNode, getAReturnValueFlowNode,
Parameter.getDefault, Scope.getEntryNode / getANormalExit etc.
with CFG-side bridges through Cfg::ControlFlowNode.
The legacy Flow.qll / Essa.qll stack is untouched and remains
available for queries that import it directly.
Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
46 lines
1.6 KiB
Plaintext
46 lines
1.6 KiB
Plaintext
import python
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
import semmle.python.dataflow.new.DataFlow
|
|
private import semmle.python.dataflow.new.internal.DataFlowPrivate
|
|
import FlowTest
|
|
|
|
module MaximalFlowTest implements FlowTestSig {
|
|
string flowTag() { result = "flow" }
|
|
|
|
predicate relevantFlow(DataFlow::Node source, DataFlow::Node sink) {
|
|
source != sink and
|
|
MaximalFlows::flow(source, sink) and
|
|
// exclude ModuleVariableNodes (which have location 0:0:0:0)
|
|
not sink instanceof DataFlow::ModuleVariableNode
|
|
}
|
|
}
|
|
|
|
import MakeTest<MakeTestSig<MaximalFlowTest>>
|
|
|
|
/**
|
|
* A configuration to find all "maximal" flows.
|
|
* To be used on small programs.
|
|
*/
|
|
module MaximalFlowsConfig implements DataFlow::ConfigSig {
|
|
predicate isSource(DataFlow::Node node) {
|
|
exists(node.getLocation().getFile().getRelativePath()) and
|
|
not node.asCfgNode() instanceof Cfg::CallNode and
|
|
not node.asCfgNode().getNode() instanceof Return and
|
|
not node instanceof DataFlow::ParameterNode and
|
|
not node instanceof DataFlow::PostUpdateNode and
|
|
// not node.asExpr() instanceof FunctionExpr and
|
|
// not node.asExpr() instanceof ClassExpr and
|
|
not DataFlow::localFlowStep(_, node)
|
|
}
|
|
|
|
predicate isSink(DataFlow::Node node) {
|
|
exists(node.getLocation().getFile().getRelativePath()) and
|
|
not any(Cfg::CallNode c).getArg(_) = node.asCfgNode() and
|
|
not isArgumentNode(node, _, _) and
|
|
not node.asCfgNode().(Cfg::NameNode).getId().matches("SINK%") and
|
|
not DataFlow::localFlowStep(node, _)
|
|
}
|
|
}
|
|
|
|
module MaximalFlows = DataFlow::Global<MaximalFlowsConfig>;
|