mirror of
https://github.com/github/codeql.git
synced 2026-06-24 22:27:03 +02:00
717ff62d70
Preparatory refactor for the shared-CFG dataflow migration. Deprecates the AstNode.getAFlowNode() cached predicate on the public Python QL API and rewrites all ~140 internal callers across lib/, src/, test/, and tools/ from `expr.getAFlowNode() = cfgNode` to `cfgNode.getNode() = expr`, using ControlFlowNode.getNode() which already exists in Flow.qll. The predicate itself is preserved (with a deprecation note pointing at the new pattern) so external users do not experience churn — they can migrate at their own pace and the AST/CFG hierarchies still get the intended untangling once the deprecation eventually elapses. Semantic noop verified by: - All 361 lib/ + src/ queries compile clean. - All 122 ControlFlow + PointsTo library-tests pass. - All 64 dataflow library-tests pass. - All 113 Variables/Exceptions/Expressions/Statements/Functions/Imports/ Security/CWE-798/ModificationOfParameterWithDefault query-tests pass. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
43 lines
1.4 KiB
Plaintext
43 lines
1.4 KiB
Plaintext
import python
|
|
|
|
private predicate empty_sequence(Expr e) {
|
|
exists(SsaVariable var | var.getAUse().getNode() = e |
|
|
empty_sequence(var.getDefinition().getNode())
|
|
)
|
|
or
|
|
e instanceof List and not exists(e.(List).getAnElt())
|
|
or
|
|
e instanceof Tuple and not exists(e.(Tuple).getAnElt())
|
|
or
|
|
e.(StringLiteral).getText().length() = 0
|
|
}
|
|
|
|
/* This has the potential for refinement, but we err on the side of fewer false positives for now. */
|
|
private predicate probably_non_empty_sequence(Expr e) { not empty_sequence(e) }
|
|
|
|
/** A loop which probably defines v */
|
|
private Stmt loop_probably_defines(Variable v) {
|
|
exists(Name defn | defn.defines(v) and result.contains(defn) |
|
|
probably_non_empty_sequence(result.(For).getIter())
|
|
or
|
|
probably_non_empty_sequence(result.(While).getTest())
|
|
)
|
|
}
|
|
|
|
/** Holds if the variable used by `use` is probably defined in a loop */
|
|
predicate probably_defined_in_loop(Name use) {
|
|
exists(Stmt loop, ControlFlowNode loopCfg, ControlFlowNode useCfg |
|
|
loop = loop_probably_defines(use.getVariable()) and
|
|
loopCfg.getNode() = loop and
|
|
useCfg.getNode() = use and
|
|
loopCfg.strictlyReaches(useCfg)
|
|
)
|
|
}
|
|
|
|
/** Holds if `s` is a loop that probably executes at least once */
|
|
predicate loop_probably_executes_at_least_once(Stmt s) {
|
|
probably_non_empty_sequence(s.(For).getIter())
|
|
or
|
|
probably_non_empty_sequence(s.(While).getTest())
|
|
}
|