mirror of
https://github.com/github/codeql.git
synced 2026-05-27 17:41:24 +02:00
0a9946121b
Migrate 27 queries under python/ql/src/ from legacy CFG types (CallNode/AttrNode/NameNode/etc.) to the shared-CFG-based 'Cfg::' namespace, matching the dataflow API surface introduced earlier on this branch. ModificationOfParameterWithDefaultCustomizations.qll is rewritten on top of BarrierGuard, removing the last legacy ESSA dependency in that file. UnguardedNextInGenerator.ql still uses ESSA and bridges to the new CFG via Cfg::CallNode.getNode(). Also reformat 14 library and query files that had drifted from the formatter. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
46 lines
1.5 KiB
Plaintext
46 lines
1.5 KiB
Plaintext
/**
|
|
* @name Modification of dictionary returned by locals()
|
|
* @description Modifications of the dictionary returned by locals() are not propagated to the local variables of a function.
|
|
* @kind problem
|
|
* @tags quality
|
|
* reliability
|
|
* correctness
|
|
* @problem.severity warning
|
|
* @sub-severity low
|
|
* @precision very-high
|
|
* @id py/modification-of-locals
|
|
*/
|
|
|
|
import python
|
|
private import semmle.python.ApiGraphs
|
|
private import semmle.python.controlflow.internal.Cfg as Cfg
|
|
|
|
predicate originIsLocals(Cfg::ControlFlowNode n) {
|
|
API::builtin("locals").getReturn().getAValueReachableFromSource().asCfgNode() = n
|
|
}
|
|
|
|
predicate modification_of_locals(Cfg::ControlFlowNode f) {
|
|
originIsLocals(f.(Cfg::SubscriptNode).getObject()) and
|
|
(f.isStore() or f.isDelete())
|
|
or
|
|
exists(string mname, Cfg::AttrNode attr |
|
|
attr = f.(Cfg::CallNode).getFunction() and
|
|
originIsLocals(attr.getObject(mname))
|
|
|
|
|
mname in ["pop", "popitem", "update", "clear"]
|
|
)
|
|
}
|
|
|
|
from AstNode a, Cfg::ControlFlowNode f
|
|
where
|
|
modification_of_locals(f) and
|
|
a = f.getNode() and
|
|
// in module level scope `locals() == globals()`
|
|
// see https://docs.python.org/3/library/functions.html#locals
|
|
// FP report in https://github.com/github/codeql/issues/6674
|
|
not a.getScope() instanceof Module and
|
|
// in class level scope `locals()` reflects the class namespace,
|
|
// so modifications do take effect.
|
|
not a.getScope() instanceof Class
|
|
select a, "Modification of the locals() dictionary will have no effect on the local variables."
|