mirror of
https://github.com/github/codeql.git
synced 2026-08-03 00:43:00 +02:00
717ff62d70
Preparatory refactor for the shared-CFG dataflow migration. Deprecates the AstNode.getAFlowNode() cached predicate on the public Python QL API and rewrites all ~140 internal callers across lib/, src/, test/, and tools/ from `expr.getAFlowNode() = cfgNode` to `cfgNode.getNode() = expr`, using ControlFlowNode.getNode() which already exists in Flow.qll. The predicate itself is preserved (with a deprecation note pointing at the new pattern) so external users do not experience churn — they can migrate at their own pace and the AST/CFG hierarchies still get the intended untangling once the deprecation eventually elapses. Semantic noop verified by: - All 361 lib/ + src/ queries compile clean. - All 122 ControlFlow + PointsTo library-tests pass. - All 64 dataflow library-tests pass. - All 113 Variables/Exceptions/Expressions/Statements/Functions/Imports/ Security/CWE-798/ModificationOfParameterWithDefault query-tests pass. Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
39 lines
1.4 KiB
Plaintext
39 lines
1.4 KiB
Plaintext
/**
|
|
* @name Result of integer division may be truncated
|
|
* @description The arguments to a division statement may be integers, which
|
|
* may cause the result to be truncated in Python 2.
|
|
* @kind problem
|
|
* @tags maintainability
|
|
* correctness
|
|
* @problem.severity warning
|
|
* @sub-severity high
|
|
* @precision very-high
|
|
* @id py/truncated-division
|
|
*/
|
|
|
|
import python
|
|
private import LegacyPointsTo
|
|
|
|
from BinaryExpr div, ControlFlowNode left, ControlFlowNode right
|
|
where
|
|
// Only relevant for Python 2, as all later versions implement true division
|
|
major_version() = 2 and
|
|
exists(BinaryExprNode bin, Value lval, Value rval |
|
|
bin.getNode() = div and
|
|
bin.getNode().getOp() instanceof Div and
|
|
bin.getLeft().(ControlFlowNodeWithPointsTo).pointsTo(lval, left) and
|
|
lval.getClass() = ClassValue::int_() and
|
|
bin.getRight().(ControlFlowNodeWithPointsTo).pointsTo(rval, right) and
|
|
rval.getClass() = ClassValue::int_() and
|
|
// Ignore instances where integer division leaves no remainder
|
|
not lval.(NumericValue).getIntValue() % rval.(NumericValue).getIntValue() = 0 and
|
|
not bin.getNode().getEnclosingModule().hasFromFuture("division") and
|
|
// Filter out results wrapped in `int(...)`
|
|
not exists(CallNode c |
|
|
c = ClassValue::int_().getACall() and
|
|
c.getAnArg() = bin
|
|
)
|
|
)
|
|
select div, "Result of division may be truncated as its $@ and $@ arguments may both be integers.",
|
|
left, "left", right, "right"
|