Merge pull request #10498 from Marcono1234/marcono1234/compilation-unit-simple-name-type

Java: Add `CompilationUnit.getATypeInScope()`

java/ql/lib/change-notes/2022-09-20-CompilationUnit-getATypeInScope.md

@@ -0,0 +1,4 @@
+---
+category: feature
+---
+* Added the predicate `CompilationUnit.getATypeInScope()`.

java/ql/lib/semmle/code/java/CompilationUnit.qll

@@ -31,5 +31,38 @@ class CompilationUnit extends Element, File {
    */
   Module getModule() { cumodule(this, result) }
 
+  /**
+   * Gets a type which is available in the top-level scope of this compilation unit.
+   * This can be a type:
+   * - declared in this compilation unit as top-level type
+   * - imported with an `import` declaration
+   * - declared in the same package as this compilation unit
+   * - declared in the package `java.lang`
+   *
+   * This predicate not consider "shadowing", it can have types as result whose simple name is
+   * shadowed by another type in scope.
+   */
+  ClassOrInterface getATypeInScope() {
+    // See "Shadowing", https://docs.oracle.com/javase/specs/jls/se17/html/jls-6.html#jls-6.4.1
+    // Currently shadowing is not considered
+    result.(TopLevelType).getCompilationUnit() = this
+    or
+    exists(Import importDecl | importDecl.getCompilationUnit() = this |
+      result =
+        [
+          importDecl.(ImportStaticTypeMember).getATypeImport(),
+          importDecl.(ImportType).getImportedType(),
+          importDecl.(ImportStaticOnDemand).getATypeImport(),
+          importDecl.(ImportOnDemandFromType).getAnImport(),
+          importDecl.(ImportOnDemandFromPackage).getAnImport(),
+        ]
+    )
+    or
+    // From same package or java.lang, see https://docs.oracle.com/javase/specs/jls/se17/html/jls-7.html
+    result.(TopLevelType).getPackage() = this.getPackage()
+    or
+    result.(TopLevelType).getPackage().hasName("java.lang")
+  }
+
   override string getAPrimaryQlClass() { result = "CompilationUnit" }
 }