From 323ccc8cea0f996f0d95f4455f385e27303af404 Mon Sep 17 00:00:00 2001
From: Joe Farebrother <joefarebrother@github.com>
Date: Wed, 13 Oct 2021 14:31:23 +0100
Subject: [PATCH] Add query to find non US spelling

---
 ql/src/queries/style/docs/NonUSSpelling.ql | 38 ++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 ql/src/queries/style/docs/NonUSSpelling.ql

diff --git a/ql/src/queries/style/docs/NonUSSpelling.ql b/ql/src/queries/style/docs/NonUSSpelling.ql
new file mode 100644
index 00000000000..8861629ca87
--- /dev/null
+++ b/ql/src/queries/style/docs/NonUSSpelling.ql
@@ -0,0 +1,38 @@
+/**
+ * @name Non US spelling
+ * @description QLDocs shold use US spelling.
+ * @kind problem
+ * @problem.severity warning
+ * @id ql/non-us-spelling
+ * @tags maintainability
+ * @precision very-high
+ */
+
+import ql
+
+predicate non_us_word(string wrong, string right) {
+  exists(string s |
+    wrong = s.splitAt("/", 0) and
+    right = s.splitAt("/", 1) and
+    s = ["colour/color", "authorise/authorize", "analyse/analyze"]
+  )
+}
+
+bindingset[s]
+predicate contains_non_us_spelling(string s, string wrong, string right) {
+  non_us_word(wrong, right) and
+  (
+    s.matches("%" + wrong + "%") and
+    wrong != "analyse"
+    or
+    // analyses (as a noun) is fine
+    s.regexpMatch(".*analyse[^s].*") and
+    wrong = "analyse"
+  )
+}
+
+from QLDoc doc, string wrong, string right
+where contains_non_us_spelling(doc.getContents().toLowerCase(), wrong, right)
+select doc,
+  "This QLDoc comment contains the non-US spelling '" + wrong + "', which should instead be '" +
+    right + "'."